【vb.net】エクセルマクロファイル（.xlsm）のシートをコピーする

Imports Microsoft.Office.Interop
Imports System.Runtime.InteropServices

Public Class Form1

    Public Const TEMPLATE = "｛ディレクトリ｝\Template.xlsm"
    Public Const OUTFOLDER = "｛ディレクトリ｝\OutPut"

    ''' <summary>
    ''' 画面読み込み時の処理を行います。
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        txtOutFolder.Text = OUTFOLDER
    End Sub

    ''' <summary>
    ''' ［出力］ボタンクリック時の処理を行います。
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

        Dim strOutFileName As String = ""

        Dim xlsApplication As Excel.Application = Nothing
        Dim xlsWorkbooks As Excel.Workbooks = Nothing
        Dim xlsWorkbook As Excel.Workbook = Nothing
        Dim xlsSheets As Excel.Sheets = Nothing

        Dim xlsWorkSheet1 As Excel.Worksheet = Nothing
        Dim xlsWorkSheet2 As Excel.Worksheet = Nothing
        Dim xlsWorkSheet3 As Excel.Worksheet = Nothing

        Dim xlsRange As Excel.Range = Nothing


        Try
            strOutFileName = txtOutFolder.Text & "\" & DateTime.Now.ToString("yyyyMMdd-HHmmss") & ".xlsm"

            'Excelアプリケーションを起動
            xlsApplication = New Excel.Application
            xlsApplication.Visible = False
            xlsApplication.DisplayAlerts = False

            'Workbooksコレクションを生成
            xlsWorkbooks = xlsApplication.Workbooks

            'Workbookオブジェクトを生成
            xlsWorkbook = xlsWorkbooks.Open(TEMPLATE)

            'Sheetsコレクションを生成
            xlsSheets = xlsWorkbook.Sheets

            xlsWorkSheet1 = xlsSheets.Item("テンプレート")
            xlsWorkSheet2 = xlsSheets.Item(xlsSheets.Count)
            xlsWorkSheet1.Copy(After:=xlsWorkSheet2)

            'Worksheetオブジェクトを生成。コピーしたシートを取得
            xlsWorkSheet3 = xlsSheets.Item(xlsSheets.Count)
            xlsWorkSheet3.Name = "出力"
            'Rangeオブジェクトを生成
            xlsRange = xlsWorkSheet3.Cells()

            'コピーしたシートへの書き込み
            xlsRange(1, 2) = "TEST PJ １"
            xlsRange(4, 1) = 1
            xlsRange(4, 2) = "テスト"
            xlsRange(5, 1) = 1234
            xlsRange(6, 1) = -1234
            xlsRange(7, 2) = -12
            xlsRange(7, 3) = -24
            xlsRange(7, 4) = 48

            'xksm形式で名前をつけて保存
            xlsWorkbook.SaveAs(Filename:=strOutFileName, FileFormat:=Excel.XlFileFormat.xlOpenXMLWorkbookMacroEnabled)

            MessageBox.Show("完了しました")

        Catch ex As Exception

            MessageBox.Show(ex.Message)

        Finally

            'Rangeオブジェクトの解放
            Marshal.ReleaseComObject(xlsRange)

            'xlsWorkSheetオブジェクトの解放
            Marshal.ReleaseComObject(xlsWorkSheet1)
            Marshal.ReleaseComObject(xlsWorkSheet2)
            Marshal.ReleaseComObject(xlsWorkSheet3)

            'Sheetsオブジェクトの解放
            Marshal.ReleaseComObject(xlsSheets)

            'Workbookオブジェクトを解放
            Marshal.ReleaseComObject(xlsWorkbook)

            'Workbooksオブジェクトを解放
            Marshal.ReleaseComObject(xlsWorkbooks)

            '保存時の問合せダイアログ表示を有りに戻す
            xlsApplication.DisplayAlerts = True

            'Excelアプリケーションを閉じる 
            xlsApplication.Quit()

            'Excel.Applicationオブジェクトを解放 
            Marshal.ReleaseComObject(xlsApplication)

        End Try

    End Sub

End Class

xlsSheets.Item("テンプレート").Copy(After:=xlsSheets.Item(xlsSheets.Count))